Instructivo de Pub/Sub de Terraform (2ª gen.)

Configure su entorno

En este instructivo, ejecutarás comandos en Cloud Shell. Cloud Shell es un entorno de shell con Google Cloud CLI ya instalada, incluida Google Cloud CLI, y valores ya establecidos para el proyecto actual. La inicialización de Cloud Shell puede tomar varios minutos:

Abra Cloud Shell

Prepara la aplicación

En Cloud Shell, sigue los siguientes pasos:

1. Clona el repositorio de la app de muestra en tu instancia de Cloud Shell:

   git clone https://github.com/GoogleCloudPlatform/nodejs-docs-samples.git

2. Ve al directorio que contiene el código de muestra de Cloud Functions, como sigue:

   cd nodejs-docs-samples/functions/v2/helloPubSub/

   La muestra de Node.js que se usa en este instructivo es una función “Hello World” básica de Pub/Sub.

3. Crea un archivo ZIP que contenga el código fuente de la función que Terraform subirá a un bucket de Cloud Storage:

   zip -r function-source.zip .
   

   Ten en cuenta que la raíz del archivo ZIP debe ser el directorio raíz del código fuente de la función, por lo que el comando anterior incluye los archivos dentro del directorio helloworld, pero no incluye el directorio en sí.

Crea tu archivo main.tf

1. En el directorio nodejs-docs-samples/functions/, crea un archivo main.tf para la configuración de Terraform:

   touch main.tf
   

2. Copia esta configuración de Terraform en tu archivo main.tf:

   terraform {
     required_providers {
       google = {
         source  = "hashicorp/google"
         version = ">= 4.34.0"
       }
     }
   }
   
   resource "random_id" "bucket_prefix" {
     byte_length = 8
   }
   
   resource "google_service_account" "default" {
     account_id   = "test-gcf-sa"
     display_name = "Test Service Account"
   }
   
   resource "google_pubsub_topic" "default" {
     name = "functions2-topic"
   }
   
   resource "google_storage_bucket" "default" {
     name                        = "${random_id.bucket_prefix.hex}-gcf-source" # Every bucket name must be globally unique
     location                    = "US"
     uniform_bucket_level_access = true
   }
   
   data "archive_file" "default" {
     type        = "zip"
     output_path = "/tmp/function-source.zip"
     source_dir  = "function-source/"
   }
   
   resource "google_storage_bucket_object" "default" {
     name   = "function-source.zip"
     bucket = google_storage_bucket.default.name
     source = data.archive_file.default.output_path # Path to the zipped function source code
   }
   
   resource "google_cloudfunctions2_function" "default" {
     name        = "function"
     location    = "us-central1"
     description = "a new function"
   
     build_config {
       runtime     = "nodejs16"
       entry_point = "helloPubSub" # Set the entry point
       environment_variables = {
         BUILD_CONFIG_TEST = "build_test"
       }
       source {
         storage_source {
           bucket = google_storage_bucket.default.name
           object = google_storage_bucket_object.default.name
         }
       }
     }
   
     service_config {
       max_instance_count = 3
       min_instance_count = 1
       available_memory   = "256M"
       timeout_seconds    = 60
       environment_variables = {
         SERVICE_CONFIG_TEST = "config_test"
       }
       ingress_settings               = "ALLOW_INTERNAL_ONLY"
       all_traffic_on_latest_revision = true
       service_account_email          = google_service_account.default.email
     }
   
     event_trigger {
       trigger_region = "us-central1"
       event_type     = "google.cloud.pubsub.topic.v1.messagePublished"
       pubsub_topic   = google_pubsub_topic.default.id
       retry_policy   = "RETRY_POLICY_RETRY"
     }
   }

3. Edita el archivo main.tf a fin de asegurarte de que tenga los valores correctos para los siguientes elementos. Debes editar este archivo cada vez que cambie la configuración (por ejemplo, para usar un entorno de ejecución diferente o implementar una función diferente):

   • Entorno de ejecución: en este ejemplo, el entorno de ejecución es nodejs16.
   • Punto de entrada de la función: en este ejemplo, el punto de entrada de la función es helloPubSub.
   • Ruta al archivo ZIP: en este ejemplo, si colocaste el archivo main.tf en el directorio nodejs-docs-samples/functions/ como se describió antes, la ruta es ./v2/helloPubSub/function-source.zip.

Inicialice Terraform

1. En Cloud Shell, ejecuta el siguiente comando para inicializar Terraform:

   docker run -v $(pwd):/app -w /app hashicorp/terraform:0.12.0 init
   

   Usa la imagen de Docker pública de Terraform. Docker ya está instalado en Cloud Shell. El directorio de trabajo actual se activa como un volumen para que el contenedor de Docker pueda leer el archivo de configuración de Terraform.

2. Ejecuta este comando para agregar los complementos necesarios y compilar el directorio .terraform:

   terraform init
   

Valida la configuración de Terraform

Obtén una vista previa de la configuración de Terraform. Este paso es opcional, pero te permite verificar que la sintaxis de main.tf sea correcta. Este comando muestra una vista previa de los recursos que se crearán:

terraform plan

Aplica la configuración de Terraform

Aplica la configuración para implementar la función. Cuando se te solicite, ingresa yes:

terraform apply

Activa la función

Para probar la función de Pub/Sub, sigue estos pasos:

1. Publica un mensaje en el tema (en este ejemplo, el nombre del tema es functions2-topic):

   gcloud pubsub topics publish TOPIC_NAME --message="Friend"

2. Lee los registros de la función para ver el resultado, en el que FUNCTION_NAME es el nombre de tu función (en este ejemplo, el nombre de la función es solo function):

   gcloud beta functions logs read FUNCTION_NAME --gen2

   Deberías ver un resultado de registro que incluya tu nuevo mensaje “Amigable”.

Realiza una limpieza

Después de completar el instructivo, puedes borrar todo lo que creaste para no incurrir en más costos.

Terraform te permite quitar todos los recursos definidos en el archivo de configuración mediante la ejecución del comando terraform destroy:

terraform destroy

Ingresa yes para permitir que Terraform borre tus recursos.