[go: nahoru, domu]
Aller au contenu

« Projet:Communes de France/Requêtes Wikidata » : différence entre les versions

Ajouter des liens
Une page de Wikipédia, l'encyclopédie libre.
Navigation interactive dans l’historique
← Modification précédente
Contenu supprimé Contenu ajouté
VisuelWikicode
Roland45 (discuter | contributions)
415 040 modifications
Annulation de la modification de Roland45 (d)
Balise : Annulation
Roland45 (discuter | contributions)
415 040 modifications
 
(Une version intermédiaire par le même utilisateur non affichée)
Ligne 168 : Ligne 168 :
|label=EPCI actuels
|label=EPCI actuels
}}
}}
Noter que le nom Wikidata n'est pas toujours le bon libellé de l'EPCI. Exemple : [[Communauté d'agglomération Beaune Côte et Sud]] apparait dans WD sous la forme ''Beaune Côte et Sud'' ou [[Communauté de communes du Haut Allier]] sous la forme ''Communauté de communes du Haut-Allier''.



==== Métropole ====
==== Métropole ====

Dernière version du 28 août 2024 à 15:38

Cette page décrit un ensemble de requêtes Wikidata permettant de lister les divisions françaises par nature

Liste de communes

[modifier | modifier le code]

Communes de France et DROM (Collectivités relevant de l'article 72 de la Constitution)

[modifier | modifier le code]

Au , il existe dans Wikidata 34 934 communes en France métropolitaine + DROM (34 944 communes au ). Cette liste est conforme à la liste officielle de l'Insee. Paris ayant un statut particulier n'apparaît pas dans cette requête. 

# Au 1er janvier 2024, il y avait 34 934 communes en France + la Ville de Paris
SELECT ?insee ?commune ?nom ?article
WHERE {
  BIND ( "2024-01-01"^^xsd:dateTime as ?dateRecherche ) # Au 1er janvier 2024
  ?commune p:P374 ?P374node . # existence d'un code Insee
    ?P374node ps:P374 ?insee . # valeur du code Insee
    OPTIONAL { ?P374node pq:P580 ?dateDébutCode . } # date de début du code Insee
    OPTIONAL { ?P374node pq:P582 ?dateFinCode . } # date de fin du code Insee
    FILTER ( !BOUND(?dateDébutCode) || ?dateDébutCode <= ?dateRecherche ) # ancien code Insee
    FILTER ( !BOUND(?dateFinCode) || ?dateFinCode > ?dateRecherche ) # futur code Insee
  ?commune wdt:P31 wd:Q484170 . # nature de commune
    OPTIONAL { ?commune wdt:P571 ?dateCréation . } # date de création
    OPTIONAL { ?commune wdt:P576 ?dateDissolution . } # date de dissolution
    FILTER ( !BOUND(?dateCréation) || ?dateCréation <= ?dateRecherche ) # communes futures
    FILTER ( !BOUND(?dateDissolution) || ?dateDissolution > ?dateRecherche ) # communes passées
   ?commune p:P1448 ?P1448node . # existence d'un nom
    ?P1448node ps:P1448 ?nom . # valeur du nom
    FILTER( lang(?nom)="fr" ). # nom en français
    MINUS { ?P1448node pq:P2241 ?dépréciationNom . } # nom erroné
    OPTIONAL { ?P1448node pq:P580 ?dateDébutNom . } # date de début du nom
    OPTIONAL { ?P1448node pq:P582 ?dateFinNom . } # date de fin du nom
    FILTER ( !BOUND(?dateDébutNom) || ?dateDébutNom <= ?dateRecherche ) # ancien nom
    FILTER ( !BOUND(?dateFinNom) || ?dateFinNom > ?dateRecherche ) # futur nom
  OPTIONAL { #article Wikipédia
    ?article schema:about ?commune .    
    ?article schema:isPartOf <https://fr.wikipedia.org/> .
    }  
}
ORDER BY (?insee)

Cliquez pour essayer !

Communes d'un département donné (exemple de la Dordogne)

[modifier | modifier le code]
# Au 1er janvier 2024, il y avait 503 communes dans le département de la Dordogne
SELECT ?insee ?commune ?nom ?article
WHERE {
  BIND ( "2024-01-01"^^xsd:dateTime as ?dateRecherche ) # Au 1er janvier 2024
  ?commune p:P374 ?P374node . # existence d'un code Insee
    ?P374node ps:P374 ?insee . # valeur du code Insee
    OPTIONAL { ?P374node pq:P580 ?dateDébutCode . } # date de début du code Insee
    OPTIONAL { ?P374node pq:P582 ?dateFinCode . } # date de fin du code Insee
    FILTER ( !BOUND(?dateDébutCode) || ?dateDébutCode <= ?dateRecherche ) # ancien code Insee
    FILTER ( !BOUND(?dateFinCode) || ?dateFinCode > ?dateRecherche ) # futur code Insee
  ?commune wdt:P31 wd:Q484170 . # nature de commune
    OPTIONAL { ?commune wdt:P571 ?dateCréation . } # date de création
    OPTIONAL { ?commune wdt:P576 ?dateDissolution . } # date de dissolution
    FILTER ( !BOUND(?dateCréation) || ?dateCréation <= ?dateRecherche ) # communes futures
    FILTER ( !BOUND(?dateDissolution) || ?dateDissolution > ?dateRecherche ) # communes passées
  
  ?commune wdt:P131 wd:Q3357 . # commune dans le département de la Dordogne - pour un autre département remplacer Q3357 par l'élément WD du département
    
   ?commune p:P1448 ?P1448node . # existence d'un nom
    ?P1448node ps:P1448 ?nom . # valeur du nom
    FILTER( lang(?nom)="fr" ). # nom en français
    MINUS { ?P1448node pq:P2241 ?dépréciationNom . } # nom erroné
    OPTIONAL { ?P1448node pq:P580 ?dateDébutNom . } # date de début du nom
    OPTIONAL { ?P1448node pq:P582 ?dateFinNom . } # date de fin du nom
    FILTER ( !BOUND(?dateDébutNom) || ?dateDébutNom <= ?dateRecherche ) # ancien nom
    FILTER ( !BOUND(?dateFinNom) || ?dateFinNom > ?dateRecherche ) # futur nom
  OPTIONAL { #article Wikipédia
    ?article schema:about ?commune .    
    ?article schema:isPartOf <https://fr.wikipedia.org/> .
    }  
}
ORDER BY (?insee)

Cliquez pour essayer !

Communes de la Polynésie française

[modifier | modifier le code]

Au , il existe dans Wikidata 48 communes en Polynésie française. 

SELECT ?insee ?commune ?communeLabel
WHERE {
  ?commune p:P374 ?P374node .                 # existence code INSEE
    ?P374node ps:P374 ?insee .                  # valeur code INSEE
  ?commune wdt:P31 wd:Q84598477.                # commune de Polynésie française
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" } # noms des communes
}
ORDER BY (?insee)

Cliquez pour essayer !

Communes de la Nouvelle-Calédonie

[modifier | modifier le code]

Au , il existe dans Wikidata 33 communes en Nouvelle-Calédonie. 

SELECT ?insee ?commune ?communeLabel
WHERE {
  ?commune p:P374 ?P374node .                 # existence code INSEE
    ?P374node ps:P374 ?insee .                  # valeur code INSEE
  ?commune wdt:P31 wd:Q84669937.                # commune de Nouvelle-Calédonie
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" } # noms des communes
}
ORDER BY (?insee)

Cliquez pour essayer !

Listes de divisions (hors communes)

[modifier | modifier le code]

Cantons

[modifier | modifier le code]

Cantons en vigueur

[modifier | modifier le code]

Au , il existe dans Wikidata 2 054 cantons : 2041 hors Mayotte, 13 dans Mayotte. Cette liste est conforme à la liste officielle de l'Insee. 

SELECT ?insee ?canton ?cantonLabel ?nomoff
WHERE {
  ?canton p:P2506 ?P2506node .                   # existence code INSEE
    ?P2506node ps:P2506 ?insee .                 # valeur code INSEE
    FILTER NOT EXISTS {?P2506node pq:P582 [] .}  # retrait anciens codes insee
  ?canton wdt:P31 wd:Q18524218.                  # canton
  FILTER NOT EXISTS {?P31node pq:P184188 [] .}   # retrait anciens cantons
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" } # noms des cantons
}
ORDER BY (?insee)

Cliquez pour essayer !

Anciens cantons

[modifier | modifier le code]

Au , il existe dans Wikidata 4 043 anciens cantons. 

SELECT ?insee ?canton ?cantonLabel ?nomoff
WHERE {
  ?canton p:P2506 ?P2506node .                   # existence code INSEE
    ?P2506node ps:P2506 ?insee .                 # valeur code INSEE
  ?canton wdt:P31 wd:Q184188.                    # ancien canton
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" } # noms des cantons
}
ORDER BY (?insee)

Cliquez pour essayer !

Arrondissements

[modifier | modifier le code]

Au , il existe dans Wikidata 333 arrondissements en France métropolitaine + DROM. Cette liste est conforme à la liste officielle de l'Insee. 

SELECT ?insee ?arron ?arronLabel
WHERE {
  ?arron p:P3423 ?P3423node .                    # existence code INSEE
    ?P3423node ps:P3423 ?insee .                  # valeur code INSEE
    FILTER NOT EXISTS {?P3423node pq:P582 [] .}  # retrait anciens codes insee
  ?arron wdt:P31 wd:Q194203.                     # arrondissement
    FILTER NOT EXISTS { ?arron wdt:P576 []. }    # retrait anciens arrondissements
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" } # noms des arrondissements
}
ORDER BY (?insee)
Cliquez pour essayer !

EPCI

[modifier | modifier le code]

Au , il existe dans Wikidata 1 229 EPCI en France métropolitaine + DROM. 

SELECT ?siren ?epci ?epciLabel
WHERE {
  ?epci p:P1616 ?P1616node .                            # existence code SIREN
    ?P1616node ps:P1616 ?siren .                        # valeur code SIREN
    FILTER NOT EXISTS {?P1616node pq:P582 [] .}         # retrait anciens codes SIREN
  ?epci wdt:P31 wd:Q18706073 .                          # EPCI
    FILTER NOT EXISTS { ?epci wdt:P576 []. }            # retrait anciens EPCI
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" } # noms des EPCI
}
ORDER BY (?insee)

Cliquez pour essayer !

Noter que le nom Wikidata n'est pas toujours le bon libellé de l'EPCI. Exemple : Communauté d'agglomération Beaune Côte et Sud apparait dans WD sous la forme Beaune Côte et Sud ou Communauté de communes du Haut Allier sous la forme Communauté de communes du Haut-Allier.

Métropole

[modifier | modifier le code]

Requête spécifique pour les métropoles. 

SELECT ?siren ?epci ?epciLabel ?article WHERE {
  ?epci p:P1616 ?P1616node.
  ?P1616node ps:P1616 ?siren.
  FILTER(NOT EXISTS { ?P1616node pq:P582 _:b18. })
  ?epci wdt:P31 wd:Q3333855.
  FILTER(NOT EXISTS { ?epci wdt:P576 _:b19. })
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }

 OPTIONAL { #article Wikipédia
    ?article schema:about ?epci .    
    ?article schema:isPartOf <https://fr.wikipedia.org/> .
    }  }
ORDER BY (?insee)

Cliquez pour essayer !

Départements

[modifier | modifier le code]

Au , il existe dans Wikidata 95 départements en France métropolitaine. Cette liste est conforme à la liste officielle de l'Insee. Paris ayant un statut particulier n'apparaît pas dans cette requête. 

SELECT ?insee ?departement ?departementLabel ?superf
WHERE {
  ?departement p:P2586 ?P2586node .                     # existence code INSEE
    ?P2586node ps:P2586 ?insee .                        # valeur code INSEE
    FILTER NOT EXISTS {?P2586node pq:P582 [] .}         # retrait anciens codes insee
  ?departement wdt:P31 wd:Q6465.                        # departement
    FILTER NOT EXISTS { ?departement wdt:P576 []. }     # retrait anciens départements
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" } # noms des départements
OPTIONAL { ?departement wdt:P2046 ?superf . }
}
ORDER BY (?insee)

Cliquez pour essayer !

Régions

[modifier | modifier le code]

Au , il existe dans Wikidata 18 régions en France métropolitaine + DROM. 

SELECT ?insee ?region ?regionLabel
WHERE {
  ?region p:P2585 ?P2585node .                           # existence code INSEE
    ?P2585node ps:P2585 ?insee .                         # valeur code INSEE
  ?region wdt:P31 wd:Q36784 .                           # région
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" } # noms des régions
}
ORDER BY (?insee)

Cliquez pour essayer !

Personnes liées à une commune

[modifier | modifier le code]

Personnes nées à

[modifier | modifier le code]
SELECT ?item ?itemLabel ?datenaissance ?datedeces ?image 
WHERE  
{  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".  }
?item wdt:P19 wd:Q6548.            # Q6548 : Lieu de naissance à Orléans - remplacer par l'élément Wikidata de la commune que l'on analyse.
  OPTIONAL {?item wdt:P18 ?image. }
  OPTIONAL {?item wdt:P569 ?datenaissance .} # P569 : Date de naissance
  OPTIONAL {?item wdt:P570 ?datedeces .} # P570 : Date de décès
}

Cliquez pour essayer !

Personnes décédées à

[modifier | modifier le code]
SELECT ?item ?itemLabel ?datenaissance ?datedeces ?image 
WHERE  
{  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".  }
?item wdt:P20 wd:Q6548.  # Q6548 : Lieu de décès à Orléans - remplacer par l'élément Wikidata de la commune que l'on analyse.
  OPTIONAL {?item wdt:P18 ?image. }
  OPTIONAL {?item wdt:P569 ?datenaissance .} # P569 : Date de naissance
  OPTIONAL {?item wdt:P570 ?datedeces .} # P570 : Date de décès
}

Cliquez pour essayer !

Ce document provient de « https://fr.wikipedia.org/w/index.php?title=Projet:Communes_de_France/Requêtes_Wikidata&oldid=218130533 ».